" 前処理 {{{
if exists('b:current_syntax')
	finish
endif

if !exists('main_syntax')
	let main_syntax = 'delang'
endif
" }}}

" 外部構文強調設定を読み込み {{{
let html_wrong_comments = v:true
runtime! syntax/html.vim
unlet! b:current_syntax
syntax cluster delangHTML
\ contains=@Spell,htmlTag,htmlEndTag,htmlSpecialChar,htmlComment,htmlLink
" https://dlt.kitetu.com/KNo.804C/4D58 で見掛けた注釈が異常にならないようにする。
syntax clear htmlPreProc

" TeX
" let skip_tex_syntax_inits = ''
" let g:tex_stylish = 0
" let g:tex_fast = 'M'
syntax include syntax/tex.vim
unlet! b:current_syntax

" Unix shell
let g:is_bash = v:true
syntax include @delangShellContent1 syntax/sh.vim
unlet! b:current_syntax

" PowerShell
syntax include @delangShellContent2 syntax/ps1.vim
unlet! b:current_syntax

" Mermaid
syntax include @delangCodeInclusion-mermaid-syntax syntax/mermaid.vim
unlet! b:current_syntax

" CSS
syntax include syntax/css.vim
unlet! b:current_syntax
" }}}

syntax spell toplevel
syntax sync linebreaks=1
syntax case ignore

" 大区分 {{{
" TODO: Markdown用の構文強調から写しただけで意味を理解していない
syntax match delangValid /[<>]\c[a-z\/$!]\@!/ contains=NONE transparent
syntax match delangValid /&\%(#\=\w*;\)\@!/ contains=NONE transparent

" TODO: Markdown用の構文強調から写しただけで意味を理解していない
syntax match delangError /\w\zs_\w\@=/

" TODO: Markdown用の構文強調から写しただけで意味を理解していない
" もとは@と<を即座に否定していたが，<...を否定するようにした。
syntax match delangLineStart
\ /^\%(@\|<!--\)\@!/
\ nextgroup=@delangBlock,htmlSpecialChar
syntax region delangLineStart
\ start=/^<\w\+.*[^\/]>$/ start=/^<\w\+>$/ end=/^<\/\w\+>$/
\ keepend skipempty
\ contains=@delangHTML
\ nextgroup=@delangBlock,htmlSpecialChar
syntax region delangLineStart
\ start=/^<\w\+/ end=/\/\s*>$/
\ keepend oneline skipempty
\ contains=@delangHTML
\ nextgroup=@delangBlock,htmlSpecialChar

" TODO: Markdown用の構文強調から写しただけで意味を理解していない
syntax match delangLineBreak /\s\{2,\}$/

" 別行立ての記法
syntax cluster delangBlock-Containable
\ contains=NONE
\,@delangDescription
\,delangList
syntax cluster delangBlock
\ contains=NONE
\,@delangBlock-Containable
\,@delangHeading
\,@delangNote
\,delangPartition
\,@delangQuote
\,@delangInclusion
\,delangHierarchy
\,@delangSeries
\,delangMathBlock
\,@delangCodeBlock

" 行内の記法
syntax cluster delangInline-NoLink-Internal
\ contains=NONE
\,@delangTextDecoration
\,delangMathInline
\,delangColorSample
\,htmlSpecialChar
syntax cluster delangInline-NoLink
\ contains=NONE
\,delangLineBreak
\,@delangInline-NoLink-Internal
\,delangError,delangValid
syntax cluster delangInline
\ contains=NONE
\,delangLineBreak
\,@delangInline-NoLink-Internal
\,@delangLink
\,delangError,delangValid
" }}}

" 見出し {{{
syntax region delangH1
\ matchgroup=delangH1Delimiter
\ start=/^[=＝]\ze[^=＝]/ end=/$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline
syntax region delangH1
\ matchgroup=delangH1Delimiter
\ start=/^[*＊]\ze[^*＊]\+/ end=/[^*＊]\+\zs$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline
"syntax match delangH1Delimiter
"\ /^[*]\ze[^*]\+$/
"\ contained keepend
"\ nextgroup=delangH1Title
"syntax match delangH1Title
"\ /.*/
"\ contained keepend
"syntax cluster delangH1
"\ contains=delangH1Delimiter

syntax region delangH2
\ matchgroup=delangH2Delimiter
\ start=/^[=＝]\{-2}/
\ start=/^[*＊]\{-2}/
\ start=/^[#＃]\{-2}\s\+/
\ end=/$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline

syntax region delangH3
\ matchgroup=delangH3Delimiter
\ start=/^[=＝]\{-3}/
\ start=/^[*＊]\{-3}/
\ start=/^[#＃]\{-3}\s\+/
\ end=/$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline

syntax region delangH4
\ matchgroup=delangH4Delimiter
\ start=/^[=＝]\{-4}/
\ start=/^[*＊]\{-4}/
\ start=/^[#＃]\{-4}\s\+/
\ end=/$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline

syntax region delangH5
\ matchgroup=delangH5Delimiter
\ start=/^[=＝]\{-5}/
\ start=/^[*＊]\{-5}/
\ start=/^[#＃]\{-5}\s\+/
\ end=/$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline

syntax region delangH6
\ matchgroup=delangH6Delimiter
\ start=/^[=＝]\{6,}/
\ start=/^[*＊]\{6,}/
\ start=/^[#＃]\{6,}\s\+/
\ end=/$/
\ contained keepend oneline
\ contains=delangReturnHeading,@delangInline

syntax match delangReturnHeading
\ /[<＜]$/
\ contained
\ conceal cchar=↵

syntax cluster delangHeading
\ contains=delangH[1-6]
" }}}

" 輪結記法 {{{
" 輪符
syntax region delangOutlineLink
\ matchgroup=delangOutlineLinkDelimiter
\ start=/{[:;]\?/ end=/[:;]\?}/
\ keepend oneline
\ contains=delangOutlineLinkKnumber2,delangOutlineLinkKname,delangLineStart,@Spell
\ transparent
syntax match delangOutlineLinkKname
\ /.\{-1,}/
\ contained skipwhite
\ contains=@delangInline-NoLink
\ nextgroup=delangOutlineLinkKnumber1
\ transparent
syntax match delangOutlineLinkKnumber1
\ /\s*K#\%(\x\{4}\)\?\/\%(\a-\)\?\x\{4}\%(-\x\{4}\)\?/
\ contained keepend
\ conceal
" K#/XXXXみたいな例示用
syntax match delangOutlineLinkKnumber1
\ /\s\+K#\/XXXX/
\ contained keepend
\ conceal
" そのまま表示する用
syntax match delangOutlineLinkKnumber2
\ /\s*K#\%(\x\{4}\)\?\/\%(\a-\)\?\x\{4}\%(-\x\{4}\)\?/
\ contained keepend

" #... ←こういう形式
syntax match delangHashtagLink
\ /\%(\s\+\)\zs#[^#[:blank:]]\+\ze\%(\s\+\|$\)/
\ keepend

" [...] ←こういう形式
syntax region delangURILink1
\ matchgroup=delangURILinkDelimiter
\ start=/\[\ze[^_]/ end=/[^_]\zs\]/
\ keepend oneline
\ contains=delangURILink1Title
\ transparent
syntax match delangURILink1Title
\ /.\{-1,}/
\ contained skipwhite
\ contains=@delangInline-NoLink
\ nextgroup=delangURILink1URI
\ transparent
syntax match delangURILink1URI
\ /\s\+https\?:\/\/\S\+/
\ contained keepend
\ conceal

" https://... ←こういう形式
" FIXME: 主述記法でhttps://...::の最後の「::」の判定がdelangURILink2に呑まれる
"        単純に末尾`::$`判定を加えると普通のURI記法が判定できなくなる。
syntax match delangURILink2
\ /https\?:\/\/\S*/
\ keepend

" \ /https\?:\/\/\S*\ze\%(\s\+\|\%(::\)\@!$\|::$\)/

syntax cluster delangLink
\ contains=delangOutlineLink,delangHashtagLink,delangURILink[12]
" }}}

" 文字修飾記法 {{{
" 斜
syntax region delangItalic1
\ matchgroup=delangItalicDelimiter
\ start=/\%(https\?:\)\@<!\zs\/\/\ze\S/ skip=/https\?:\/\// end=/\S\zs\/\//
\ keepend oneline
\ contains=@delangLink,delangLineStart,@Spell
\ concealends
syntax region delangItalic2
\ matchgroup=delangItalicDelimiter
\ start=/\*\ze[^*]/ end=/[^*]\zs\*/
\ keepend oneline
\ contains=@delangLink,delangLineStart,@Spell
\ concealends

" 太
syntax region delangBold1
\ matchgroup=delangBoldDelimiter
\ start=/##\ze[^#].\{-}/ end=/.\{-}[^#]\zs##/
\ keepend oneline
\ contains=@delangLink,delangLineStart,@Spell
\ concealends
syntax region delangBold2
\ matchgroup=delangBoldDelimiter
\ start=/\%(＊\|\*\*\)\ze[^＊*].\{-}/ end=/.\{-}[^＊*]\zs\%(＊\|\*\*\)/
\ keepend oneline
\ contains=@delangLink,delangLineStart,@Spell
\ concealends

" 小
syntax region delangSmall
\ matchgroup=delangSmallDelimiter
\ start=/[(（][(（]\ze.\{-}/ end=/.\{-}\zs[)）][)）]/
\ keepend
\ contains=@delangInline,delangLineStart,@Spell

" 下線
syntax region delangUnderline
\ matchgroup=delangUnderlineDelimiter
\ start=/__\ze.\{-}/ end=/.\{-}\zs__/
\ keepend
\ contains=@delangInline,delangLineStart,@Spell
\ concealends

" 打消
syntax region delangStrike
\ matchgroup=delangStrikeDelimiter
\ start=/\~\~\ze.\{-}/ end=/.\{-}\zs\~\~/
\ keepend
\ contains=@delangInline,delangLineStart,@Spell
\ concealends

" 振り仮名
syntax region delangReading
\ matchgroup=delangReadingDelimiter
\ start=/[(（][＾^]\ze.\{-}/ end=/.\{-}\zs[)）]/
\ keepend oneline
\ contains=delangLineStart,@Spell

" 鍵盤
syntax region delangKeyboard
\ matchgroup=delangKeyboardDelimiter
\ start=/\[_\ze.\{-}/ end=/.\{-}\zs_\]/
\ keepend oneline
\ contains=delangOutlineLink,delangColorSample,htmlSpecialChar,delangLineStart

" 譜
" 色見本記法との区別
syntax region delangCodeInline
\ matchgroup=delangCodeDelimiter
\ start=/[^`]*\%(%%\)\@!\zs`\ze[^`]/ skip=/```*/ end=/[^`]\zs`\ze\%([^%`]\|$\)/
\ keepend oneline
\ contains=delangLineStart
" ``が2個以上なら色見本記法との区別は不要
syntax region delangCodeInline
\ matchgroup=delangCodeDelimiter
\ start=/\zs\z(```*\)/ end=/[^`]\zs\z1\ze\%([^`]\|$\)/
\ keepend oneline
\ contains=delangLineStart

syntax cluster delangTextDecoration
\ contains=NONE
\,delangItalic[12]
\,delangBold[12]
\,delangSmall
\,delangUnderline
\,delangStrike
\,delangReading
\,delangKeyboard
\,delangCodeInline
" }}}

" 色見本記法 {{{
syntax region delangColorSample
\ matchgroup=delangColorSampleDelimiter
\ start=/%%%*(/ end=/)/
\ keepend oneline
\ contains=cssColor,delangColorSample-RGB
syntax region delangColorSample
\ matchgroup=delangColorSampleDelimiter
\ start=/%%*`/ end=/`/
\ keepend oneline
\ contains=cssColor,delangColorSample-RGB
syntax region delangColorSample
\ matchgroup=delangColorSampleDelimiter
\ start=/`/ end=/`%%/
\ keepend oneline
\ contains=cssColor,delangColorSample-RGB

syntax region delangColorSample-RGB
\ matchgroup=cssFunctionName
\ start=/rgb(/ end=/)/
\ contained extend oneline
\ contains=cssValueNumber,cssFunctionComma
" }}}

" 別行譜記法 {{{
syntax region delangCodeBlock-Internal
\ matchgroup=delangCodeDelimiter
\ start=/^\z(```*\)\ze\w*$/ end=/^\z1$/
\ contained keepend skipempty
"syntax match delangShellBlock1
"\ /^\$\s\+/
"\ contained skipwhite
"\ nextgroup=@delangShellContent1

" Highlight.jsの鍵語とVimの構文強調譜との写像
"let s:hljskw_vimsy_map = #{
"\ python: 'python',
"\ c:      'c',
"\}
"function! s:hljskw_vimsy_map.incsyn(hljskw)
"	if self->has_key(a:hljskw)
"		echo 'syntax/' .. self[a:hljskw] .. '.vim'
"	endif
"endfunction
"command! -nargs=1 TestHV call s:hljskw_vimsy_map.incsyn(<f-args>)

" 仕類記法 {{{
" FIXME: here-documentとかに含まれる有意味な空行に対応できない

syntax region delangShellBlock1
\ matchgroup=delangShellDelimiter
\ start=/^[#$%] / end=/^$/
\ contained keepend skipempty
\ contains=@delangShellContent1

syntax region delangShellBlock2
\ matchgroup=delangShellDelimiter
\ start=/^PS[^>]*> \ze\S\+/ end=/^$/
\ keepend skipempty
\ contains=@delangShellContent2
" }}}

syntax cluster delangCodeBlock
\ contains=delangCodeBlock-Internal,delangShellBlock[12]
" }}}

" 主述記法 {{{
" FIXME: 冒頭に行内記法があるとき判定が漏れる
syntax match delangDescriptionHeader
\ /^\%([>=]\|\s*-\)\@!.*::$/
\ contains=@delangInline,delangDescriptionDelimiter
syntax match delangDescriptionDelimiter
\ /::$/
\ contained
"syntax region delangDescriptionHeader
"\ matchgroup=delangDescriptionDelimiter
"\ start=/^\ze[^>=-].\+/ end=/::$/
"\ contained keepend oneline
"\ contains=@delangInline
"\ nextgroup=delangDescriptionContent

"syntax region delangDescriptionContent
"\ start=/.*/ end=/^$/
"\ contained keepend
"\ contains=@delangInline

syntax cluster delangDescription
\ contains=delangDescriptionHeader
" }}}

" 注意・補足記法 {{{
syntax region delangNoteI
\ matchgroup=delangNoteIDelimiter
\ start=/^!---*$/ end=/^---*$/
\ contained keepend skipempty
\ contains=@delangInline,@delangBlock-Containable

syntax region delangNoteII
\ matchgroup=delangNoteIIDelimiter
\ start=/^!!---*$/ end=/^---*$/
\ contained keepend skipempty
\ contains=@delangInline,@delangBlock-Containable

syntax region delangNoteIII
\ matchgroup=delangNoteIIIDelimiter
\ start=/^!!!---*$/ end=/^---*$/
\ contained keepend skipempty
\ contains=@delangInline,@delangBlock-Containable

syntax region delangNoteIQ
\ matchgroup=delangNoteIQDelimiter
\ start=/^!?---*$/ end=/^---*$/
\ contained keepend skipempty
\ contains=@delangInline,@delangBlock-Containable

syntax region delangNoteIQQ
\ matchgroup=delangNoteIQQDelimiter
\ start=/^!??---*$/ end=/^---*$/
\ contained keepend skipempty
\ contains=@delangInline,@delangBlock-Containable

syntax cluster delangNote
			\ contains=delangNoteI[IQ]*
" }}}

" 引括記法 {{{
" 輪結
syntax region delangOutlineInclusion
\ matchgroup=delangInclusionDelimiter
\ start=/^+\zeK.*\x\{4}$/ end=/$/
\ contained keepend oneline
\ contains=delangOutlineLinkKnumber2
syntax region delangOutlineInclusion
\ matchgroup=delangInclusionDelimiter
\ start=/^+\ze{/ end=/}\zs$/
\ contained keepend oneline
\ contains=delangOutlineLink

" URI
syntax region delangURIInclusion
\ matchgroup=delangInclusionDelimiter
\ start=/^+\zehttps\?:\/\// end=/$/
\ contained keepend oneline
\ contains=delangURILink2
syntax region delangURIInclusion
\ matchgroup=delangInclusionDelimiter
\ start=/^+\zeK/ end=/\x\{4}\zs\.\w\+$/
\ contained keepend oneline
\ contains=delangOutlineLinkKnumber2
syntax region delangURIInclusion
\ matchgroup=delangInclusionDelimiter
\ start=/^+\ze{/ end=/}\zs\.\w\+$/
\ contained keepend oneline
\ contains=delangOutlineLink

" 譜 {{{
" KaTeX ← TeX
syntax region delangCodeInclusion-katex
\ matchgroup=delangInclusionDelimiter
\ start=/^+``katex$/ end=/^``$/
\ contained keepend skipempty
\ contains=@texMathZoneGroup

" Mermaid
syntax region delangCodeInclusion-mermaid
\ matchgroup=delangInclusionDelimiter
\ start=/^+``mermaid$/ end=/^``$/
\ contained keepend skipempty
\ contains=@delangCodeInclusion-mermaid-syntax

syntax cluster delangCodeInclusion
\ contains=NONE
\,delangCodeInclusion-katex
\,delangCodeInclusion-mermaid
" }}}

syntax cluster delangInclusion
\ contains=
\,delangOutlineInclusion
\,delangURIInclusion
\,@delangCodeInclusion
" }}}

" 階層記法 {{{
syntax match delangHierarchy
\ /^[^<>=-].*[^-]>$/
\ keepend
\ contains=@delangInline,delangHierarchyDelimiter

"syntax region delangHierarchy
"\ matchgroup=delangHierarchyDelimiter
"\ start=/^\ze[^<>=-]\+/ start=/^\ze<\s\+/ end=/[^-]\zs>$/
"\ contained keepend oneline
"\ contains=@delangInline,delangHierarchyDelimiter

syntax match delangHierarchyDelimiter
\ />/
\ contained
" }}}

" 数学記法 {{{
" NOTE: 化学記法も一絡にしている。
" TODO:
" ほんとうはmhchem用の構文強調を用意したい。H2Oとか<->とかが適切に判定されるような。
syntax region delangMathInline
\ matchgroup=delangMathDelimiter
\ start=/\\\%(ce\)\?(/ end=/\\)/
\ keepend oneline
\ contains=delangLineStart,@texMathZoneGroup,htmlSpecialChar
\ concealends

syntax region delangMathBlock
\ matchgroup=delangMathDelimiter
\ start=/^\\\%(ce\)\?\[/ end=/\\\]$/
\ contained keepend skipempty
\ contains=@texMathZoneGroup,htmlSpecialChar
\ concealends
" }}}

" 引用記法 {{{
syntax region delangQuote1
\ matchgroup=delangQuoteDelimiter
\ start=/^>\ze[^>]\s*/ end=/$/
\ contained transparent keepend oneline
\ contains=@delangInline
\ nextgroup=delangCitation,@delangBlock

syntax region delangQuote2
\ matchgroup=delangQuoteDelimiter
\ start=/^>>$/ end=/^<<$/ end=/\ze\n---*.\+/
\ contained transparent keepend skipempty
\ contains=@delangInline
\ nextgroup=delangCitation

" FIXME: 1行の引用 (delangQuote1) の下にある----が色付かない
" FIXME: <<で終結している複数行引用 (delangQuote2) の下にある--...が誤判定される
syntax region delangCitation
\ matchgroup=delangCitationDelimiter
\ start=/^---*\ze.\+/ end=/$/
\ contained keepend oneline
\ contains=@delangInline

syntax cluster delangQuote
\ contains=delangQuote[12]
" }}}

" 区切り線記法 {{{
syntax match delangPartition
\ /^---*$/
\ contained keepend
" }}}

" 羅列記法 {{{
" checkbox記法 {{{
syntax match delangCheckBoxEmpty '\[ \]'
\ contained
\ nextgroup=@delangInline
\ conceal cchar=☐
syntax match delangCheckBoxChecked '\[x\]'
\ contained
\ nextgroup=@delangInline
\ conceal cchar=☑
" }}}

syntax region delangList
\ matchgroup=delangListDelimiter
\ start=/^\s*-\ze[^-]\+/ start=/^\s*・/ end=/$/
\ contained keepend oneline
\ contains=delangCheckBox\%(Empty\|Checked\),@delangInline
" }}}

" 前次記法 {{{
" <-
syntax region delangSeriesPrev
\ matchgroup=delangSeriesDelimiter
\ start=/^<-/ end=/$/
\ contained oneline
\ contains=@delangInline

" ->
syntax match delangSeriesNext
\ /^[^<>=-].*->$/
\ contains=@delangInline,delangSeriesDelimiter
syntax match delangSeriesDelimiter
\ /->$/
\ contained
"syntax region delangSeriesNext
"\ matchgroup=delangSeriesDelimiter
"\ start=/^\ze[^>=-]/ end=/->$/
"\ contained oneline
"\ contains=@delangInline

" <- | ->
syntax region delangSeriesPrevNext
\ matchgroup=delangSeriesDelimiter
\ start=/^<-/ end=/->$/
\ contained oneline
\ contains=@delangInline,delangSeriesMiddle
syntax match delangSeriesMiddle
\ /|/
\ contained

syntax cluster delangSeries
\ contains=delangSeries\%(Prev\)\?\%(Next\)\?
" }}}

" 強調方法 {{{
highlight default link delangH1	htmlH1
highlight default link delangH2	htmlH2
highlight default link delangH3	htmlH3
highlight default link delangH4	htmlH4
"highlight delangH4	ctermfg=Blue
highlight default link delangH5	htmlH5
"highlight delangH5	ctermfg=Red
highlight default link delangH6	htmlH6
highlight default link delangH1Delimiter	delangHeadingDelimiter
highlight default link delangH2Delimiter	delangHeadingDelimiter
highlight default link delangH3Delimiter	delangHeadingDelimiter
highlight default link delangH4Delimiter	delangHeadingDelimiter
highlight default link delangH5Delimiter	delangHeadingDelimiter
highlight default link delangH6Delimiter	delangHeadingDelimiter
highlight default link delangHeadingDelimiter	Label
highlight default link delangReturnHeading	Comment

highlight default link delangOutlineLinkDelimiter	Delimiter
highlight default link delangOutlineLinkKnumber1	htmlLink
highlight default link delangOutlineLinkKnumber2	htmlLink
"highlight default link delangOutlineLinkEye	Label
highlight default link delangHashtagLink	htmlLink
highlight default link delangURILink1URI	htmlLink
highlight default link delangURILink2	htmlLink
highlight default link delangURILinkDelimiter	Delimiter

highlight default link delangInclusionDelimiter	Delimiter

highlight default link delangItalic1	htmlItalic
highlight default link delangItalic2	htmlItalic
highlight default link delangItalicDelimiter	Delimiter
highlight default link delangBold1	htmlBold
highlight default link delangBold2	htmlBold
highlight default link delangBoldDelimiter	Delimiter
highlight default link delangSmall	Comment
highlight default link delangSmallDelimiter	Delimiter
highlight default link delangUnderline	htmlUnderline
highlight default link delangUnderlineDelimiter	Delimiter
highlight default link delangStrike	htmlStrike
highlight default link delangStrikeDelimiter	Delimiter
highlight default link delangReading	Comment
highlight default link delangReadingDelimiter	Delimiter
highlight default link delangKeyboardDelimiter	Delimiter

highlight default link delangColorSampleDelimiter	Delimiter

highlight default link delangMathDelimiter	Delimiter

highlight default link delangCodeDelimiter	Delimiter

highlight default link delangQuoteDelimiter	Comment
highlight default link delangCitationDelimiter	Comment

highlight default link delangPartition	Delimiter

highlight default link delangListDelimiter	Label
highlight default link delangCheckBox	Label

highlight default link delangHierarchyDelimiter	Directory

highlight default link delangSeriesDelimiter	Directory
highlight default link delangSeriesMiddle	delangSeriesDelimiter

highlight default link delangDescriptionHeader	Title
highlight default link delangDescriptionDelimiter	delangHeadingDelimiter

highlight default link delangNoteI	Comment
highlight default link delangNoteIDelimiter	delangNoteI
highlight delangNoteIIDelimiter
\ term=bold ctermfg=Yellow
\ gui=bold guifg=Yellow
highlight delangNoteIIIDelimiter
\ term=bold ctermfg=Red
\ gui=bold guifg=Red
highlight delangNoteIQDelimiter
\ term=bold ctermfg=Green
\ gui=bold guifg=Green
highlight delangNoteIQQDelimiter
\ term=bold ctermfg=Cyan
\ gui=bold guifg=Cyan

highlight default link delangError	Error
" }}}

" 後処理 {{{
let b:current_syntax = 'delang'
if main_syntax ==# 'delang'
	unlet main_syntax
endif
" }}}